BETA Version

Dieses Script ist noch in der Testphase!
This script is still under construction, but works

Holt die Updates von den definierten Lokationen und speichert diese lokal ab.
Get the Updates from a defined location and will save it locally.

• get-update.cmd ← Command-Script
• addons.dat ← data-file

• wget.exe ⇒ see UnxUtils
• sed.exe ⇒ see UnxUtils
• 7zip.exe ⇒ see 7zip

get-update.cmd

@echo off
set _this=get-update.cmd
set _thisdir=%CD%
 
REM Version 0.0.2 Mark Wolfgruber 21.09.2009
REM   mod: using proxy available, mod line set http_proxy=PROXYNAME 
REM   mod: using Enviroment %ProgramFiles%
REM   mod: local _logdir
REM Version 0.0.1 Mark Wolfgruber 07.07.2009
 
 
set _pichat_downloads=http://www.pichat.net/downloads
set _pichat_repository=%_pichat_downloads%/pichat_updates.ini
rem set _local_downloads=%appdata%\pichat\webserver\downloads
rem set _local_downloads=%ProgrammFiles%\pichat\server\webserver\downloads
rem set _local_downloads=D:\Data\web\80\downloads\chat-updates
set _local_downloads=.\downloads
set _local_repository=%_local_downloads%\pichat_updates.ini
set _addons=addons.dat
 
set _logging=1
rem set _logdir=%_local_downloads%
set _logdir=.
set _logfile=%_logdir%\%_this%.log
set _log="%_logfile%"
 
set _unxutils=%ProgramFiles%\UnxUtils
 
rem set http_proxy=webproxy01
set http_proxy=
set _wget="%_unxutils%\wget.exe" 
 
REM pichat.ini
REM [Updates]
REM EnableUpdates=1
REM CheckForUpdates=1
REM DownloadUpdates=1
REM UpdatesDownloadDirectory=~/pichat/updates
REM UpdatesRepository1=http://www.pichat.net/downloads/pichat_updates.ini
 
call :check_dirs
call :download_pichat
call :download_addons
 
goto end
 
::functions
:download_pichat
:download_pichat_repository
  call :msg "DOWNLOAD %_pichat_repository%" 
  %_wget% -a %_log% -O "%_local_repository%"  --cache=off %_pichat_repository%
 
:download_pichat_files
  FOR /F "eol=; tokens=2,3* delims=,=" %%I in ('find /i ^"file^" ^"%_local_repository%^"') do (
    call :msg "DOWNLOAD %_pichat_downloads%/%%I"
    %_wget% -a %_log% -O "%_local_downloads%\%%I" --cache=off %_pichat_downloads%/%%I
  )
  goto :EOF
 
:download_addons
    if exist "%_addons%" (
      call :msg "Found ADDONSFILE %_addons% ... try to downlaod entries" 
      FOR /F "eol=# tokens=1,2* delims==" %%A in (%_addons%) do (
        call :msg "DOWNLOAD %%A from %%B" 
        %_wget% -a %_log% -O "%_local_downloads%\%%A" --cache=off %%B
      )
    ) ELSE (
      call :msg "no ADDONSFILE %_addons% found!" 
    )
    goto :EOF
 
:check_dirs
  if %_logging% EQU 1 (
    if not exist "%_logdir%\." (
      md "%_logdir%"
      if not exist "%_logdir%\." (
        echo "ERROR: creating Directory: %_logdir%" i
        set _logging=0
      ) ELSE (
        call :msg "Start Logfile: %_logfile%" 
      )
    )
  )
  if %_logging% EQU 1 (
    if not exist %_log% (
      call :msg "Start Logfile: %_logfile%" 
    ) 
    if not exist %_log% (
      set _logging=0
      echo "ERROR: can not start Logfile: %_logfile%" 
    ) 
  )
  call :msg "### start %COMPUTERNAME% %_this% ###" 
 
  if not exist "%_local_downloads%\." (
    call :msg "creating Directory: %_local_downloads% " 
    md "%_local_downloads%"
    if not exist "%_local_downloads%\." (
      call :msg "### ERROR creating Directory: %_local_downloads%" i
      goto end
    ) ELSE (
      call :msg "done" 
    )
  )
  goto :EOF
:msg
  echo %date% %time% ### %~1  
  if %_logging% EQU 1 (
      echo %date% %time% ### %~1 >> %_log%
      goto :EOF
  )
:end
    call :msg "### end %COMPUTERNAME% %_this% ###" 
 
:quit

addons.dat

# Syntax:
# Filename=URL
#
# addon from godx.de
#
annabot.zip=http://www.godx.de/download/anna_latest.zip
#
# Examples from pichat.net
#
pichat_color_schemes_examples.zip=http://www.pichat.net/downloads/pichat_color_schemes_examples.zip
pichat_graphics_examples.zip=http://www.pichat.net/downloads/pichat_graphics_examples.zip
pichat_language_reference.zip=http://www.pichat.net/downloads/pichat_language_reference.zip
pichat_quizbot_examples.zip=http://www.pichat.net/downloads/pichat_quizbot_examples.zip
pichat_webcam_examples.zip=http://www.pichat.net/downloads/pichat_webcam_examples.zip
pichat_webchat_templates.zip=http://www.pichat.net/downloads/pichat_webchat_templates.zip
#
# Developers
#
pichat_sdk.zip=http://www.pichat.net/downloads/pichat_sdk.zip
pichat_sdk_tools.zip=http://www.pichat.net/downloads/pichat_sdk_tools.zip
#
# following links are downloaded by the pichat_updates.ini
# Software
#
# pichat_linux.tgz=http://www.pichat.net/downloads/pichat_linux.tgz
# pichat_win32.exe=http://www.pichat.net/downloads/pichat_win32.exe
#
# Plugins Linux
#
# http://www.pichat.net/downloads/pichat_pluginlanguage.so
# http://www.pichat.net/downloads/pichat_pluginlogbot.so
# http://www.pichat.net/downloads/pichat_pluginquizbot.so
# http://www.pichat.net/downloads/pichat_pluginwebstatus.so
#
# Plugins Windows
#
# http://www.pichat.net/downloads/pichat_pluginlanguage.dll
# http://www.pichat.net/downloads/pichat_pluginlogbot.dll
# http://www.pichat.net/downloads/pichat_pluginquizbot.dll
# http://www.pichat.net/downloads/pichat_pluginwebcam.dll
# http://www.pichat.net/downloads/pichat_pluginwebstatus.dll
# http://www.pichat.net/downloads/pichat_pluginwinamp.dll